VD trong GPE

Ta có 1 file xml có dạng :

*Những chuỗi màu đỏ đánh dấu là những chuỗi mình cần lấy giá trị  
<?xml version="1.0" encoding="UTF-8"?>*  
*<PersistentObject>*  
*<CUIDESIGN PersistentID="8ae5b13b" ClassName="CUIDESIGN">*  
***<DESIGNNUMBER DataType="8">ABCDE</DESIGNNUMBER>***  
*<AVGCALCTIME DataType="5">654557</AVGCALCTIME>*  
*</CUIDESIGN>*  
*<CUIROOT PersistentID="9c682313" ClassName="CUIROOT">*  
*<DESIGNNUMBER DataType="8">ABCDE</DESIGNNUMBER>*  
*<AVGCALCTIME DataType="5">654557</AVGCALCTIME>*  
***<DBDATE DataType="8">2015/08/14</DBDATE>***  
*<DBTIME DataType="8">04:35:28</DBTIME>*  
*</CUIROOT>*

Chuỗi cần lấy là phần bị tô đen.

Solution1 : ndu96081631

Sub Main()

Dim fso As Object, oStream As Object

Dim filePath As String, sTmp As String, sRet As String

Dim lPos1 As Long, lPos2 As Long

Dim vFile

vFile = Application.GetOpenFilename("XML Files, \*.xml")

If TypeName(vFile) = "String" Then

Set fso = CreateObject("Scripting.FileSystemObject")

filePath = CStr(vFile)

Set oStream = fso.OpenTextFile(filePath, 1)

sTmp = oStream.ReadAll

oStream.Close

lPos1 = InStr(1, sTmp, "<DESIGNNUMBER DataType=""8"">")

If lPos1 Then

sRet = Mid(sTmp, lPos1 + 27)

lPos2 = InStr(1, sRet, "<")

If lPos2 Then

sRet = Left(sRet, lPos2 - 1)

Sheets("INPUT").Range("E14").Value = sRet

End If

End If

lPos1 = 0: lPos2 = 0: sRet = Empty

lPos1 = InStr(1, sTmp, "<DBDATE DataType=""8"">")

If lPos1 Then

sRet = Mid(sTmp, lPos1 + 21)

lPos2 = InStr(1, sRet, "<")

If lPos2 Then

sRet = Left(sRet, lPos2 - 1)

Sheets("INPUT").Range("E16").Value = "'" & sRet

End If

End If

End If

End Sub

Cảm ơn bác ndu96081631,  
Sau khi edit lại code, mình up lại code hoàn thiện, file đính kèm: Test2\_1.zip .  
Nhưng trong code của bác ndu96081631   
câu lệnh: sRet = Mid(sTmp, lPos1 + 27) bị phụ thuộc vào độ dài của: lPos1 = InStr(1, sTmp, "<DESIGNNUMBER DataType=""**8**"">"), phải đến xem có bao nhiêu ký tự. Số 8 (đánh dấu màu đỏ) phải thêm 2 dấu " " . Có cách nào khắc phục được nhược điểm này không bác?

Solution2 : doveandrose

Public Sub hell()

Dim fso As Object, oStream As Object

Dim filePath As String, sTmp As String, sRet As String

Dim vFile

vFile = Application.GetOpenFilename("XML Files, \*.xml")

If TypeName(vFile) = "String" Then

Set fso = CreateObject("Scripting.FileSystemObject")

filePath = CStr(vFile)

Set oStream = fso.OpenTextFile(filePath, 1)

sTmp = oStream.ReadAll

oStream.Close

With Worksheets("INPUT")

vFile = getInfo(sTmp, "<CUIDESIGN")

.[H14].Value = vFile(1): .[H16].Value = vFile(2): .[H18].Value = vFile(3)

vFile = getInfo(sTmp, "<CUIROOT")

.[K14].Value = vFile(1): .[K16].Value = vFile(2): .[K18].Value = vFile(3)

End With

End If

End Sub

Private Function getInfo(sTmp As String, parentNode As String) As Variant

Dim arr(1 To 3), lPos1 As Long, lPos2 As Long, lStart As Long

lPos1 = InStr(sTmp, parentNode)

If lPos1 > 0 Then

arr(1) = getNodeVL(sTmp, "<DESIGNNUMBER", lPos1)

arr(2) = getNodeVL(sTmp, "<DBDATE", lPos1)

arr(3) = getNodeVL(sTmp, "<DBTIME", lPos1)

End If

getInfo = arr

End Function

Private Function getNodeVL(ByVal sTmp As String, ByVal nodeName As String, \_

ByVal lPos As Long) As String

Dim lPos2 As Long, lStart As Long

getNodeVL = ""

lPos = InStr(lPos, sTmp, nodeName) + 1

lStart = InStr(lPos, sTmp, ">") + 1

lPos2 = InStr(lPos, sTmp, "<")

If InStr(lPos, sTmp, "/") > lStart Then getNodeVL = Mid(sTmp, lStart, lPos2 - lStart)

End Function

Solution3: Batman1

Sub Main()

Dim filename, xmldoc As Object

filename = Application.GetOpenFilename("XML Files, \*.xml")

If TypeName(filename) = "String" Then

Set xmldoc = CreateObject("MSXML2.DOMDocument")

If xmldoc.Load(filename) Then

With Worksheets("INPUT")

.Range("H14").Value = xmldoc.SelectSingleNode("//PersistentObject/CUIDESIGN/DESIGNNUMBER").Text

.Range("H16").Value = xmldoc.SelectSingleNode("//PersistentObject/CUIDESIGN/DBDATE").Text

.Range("H18").Value = xmldoc.SelectSingleNode("//PersistentObject/CUIDESIGN/DBTIME").Text

.Range("K14").Value = xmldoc.SelectSingleNode("//PersistentObject/CUIROOT/DESIGNNUMBER").Text

.Range("K16").Value = xmldoc.SelectSingleNode("//PersistentObject/CUIROOT/DBDATE").Text

.Range("K18").Value = xmldoc.SelectSingleNode("//PersistentObject/CUIROOT/DBTIME").Text

End With

End If

Set xmldoc = Nothing

End If

End Sub